Является ли УС Лэнд самопиской и какие критерии самописок? : КИС Lack & УС Land

* ---------------------------------------------------------------------------
*   Печать пачки накладных и счетов фактур по запросу. Повтор параметров спе-
*   циализированной печати для группы документов определяемых в запросе
PROC pPrePrDoc()
    LOCA cOldCol:=SetColor(), nRec:=RecNo(), nOrd:=zOrd()
    LOCA GetList:={}, lExit:=TRUE, nSec:=0
    LOCA nTip:=3, dBeg:=Date(), dEnd:=Date(), cBeg:=Spac(12), cEnd:=Spac(12)
    LOCA sOp:="0755"
    S_PROC

    //  Определяю справочные переменные
    cClient     := Spac(4)

    //  Из экранной формы читаем параметры режима печати документов.
    fSwopen(16,22,7,55,cOther,3)
    @ 1,1 SAY "Пожалуйста введите код покупателя (F3) или ничего"       GET cClient             VALI IF(Empty(cClient),TRUE,Eval(bClient,cClient))
    @ 2,1 SAY "Дату начала периода документов (заказов)     "           GET dBeg
    @ 3,1 SAY "и дату окончания периода для пачки заказов   "           GET dEnd                VALI lValid({||dEnd >= dBeg},"Меньше начальной - нельзя!")
    @ 4,1 SAY "Начальный номер интервала номеров заказов"               GET cBeg
    @ 5,1 SAY "конечный номер.Номера переводятся в число"               GET cEnd
    @ 6,1 SAY "Печатаем: 1-только ТТН, 2-сч.фактуры, иначе все     "    GET nTip                PICT "9"
    READ
    fDeact(cOldCol)
    AP__INPUT

    /*  Проверяю, что был произведен режим специализированной
        печати накладных и (или) счетов фактур, т.е. программу обучили,
        как печатать документы, удовлетворяющие запросам режима */
    IF (nTip = 1) .OR. (nTip > 2)   //  Проверяем накладные
        IF ValType(apFact[1]) <> "N"
            ErrMess("В начале сделайте специализированную печать, как обычно!",cError)
            RETU
        ENDI
    ENDI
    IF (nTip = 1) .OR. (nTip > 2)   //  Проверяем счета фактуры
        IF ValType(apFact[13]) <> "N"
            ErrMess("В начале сделайте специализированную печать, как обычно!",cError)
            RETU
        ENDI
    ENDI

    /*  Проверяем запущенность ХБК, если печать документов в графическом формате
        Заведомо переменная определена, т.к. режим спецпечати уже вызывался */
    IF apFact[26] > 0 .OR. apFact[13] > 0
        IF !lgCheckXbm() THEN RETU
    ENDI

    //  Сканирую список документов по ограничителям режимов. Можно прервать процесс печати
    ftxt_act("             Прерываемо. Пожалуйста подождите окончания печати...",cHelpc,TRUE)

    zSet(PR_DAT_NUMBER)
    SET SOFT ON
    DbSeek( Dtos(dBeg) )
    SET SOFT OFF
    DO WHIL !Eof() .AND. dat <= dEnd
        BR_REPORT
        @ 1,1 SAY number
        Inkey(1)

        //***   Блок отсева записей заголовков предзаказа
        SELE PRE_SELL
        IF !Empty(cClient) .AND. client <> cClient
            DbSkip(); LOOP
        ENDI
        IF !(Val(Alltrim(number)) <= Val(Alltrim(cEnd))) .AND. (Val(Alltrim(number)) >= Val(Alltrim(cBeg)))
            DbSkip(); LOOP
        ENDI

        /*  Ожидаем ограниченное время завершения предыдущей печати системы ХБК
            в графическом режиме иначе даю небольшую паузу для досовой печати  */
        IF apFact[26] > 0 .OR. apFact[13] > 0
            lExit   := FALSE
            nSec    := 0
            WHIL nSec++ < 60    //  Попытки делаем минуту... например для заправки бумаги
                IF !(File(cPathXBK+"torg.dbf") .OR. File(cPathXBK+"dtor.dbf") .OR. File(cPathXBK+"wtorg.dbf") .OR. File(cPathXBK+"wdtor.dbf"))
                    lExit   := TRUE
                    EXIT
                ENDI
                Inkey(1)
            END
        ELSE
            Inkey(0.5)
        ENDI
        IF !lExit .OR. !zPrintReady()
            ErrMess("Сбой печати, закончилась бумага, проблемы с ХБК. Завершаю попытки печати документов!",cError)
            EXIT
        ENDI

        //  По предзаказу печатаю указанный тип документа.
        @ 1,1 SAY number
        IF nTip = 1 .OR. nTip > 2   //  Накладную в указанном формате
            pVirt(6)
        ENDI

        IF nTip = 2 .OR. nTip > 2   //  Счет фактуру в указанном формате
            IF apFact[26] > 0
                nSec    := 0
                WHIL nSec++ < 20
                    IF !(File(cPathXBK+"torg.dbf") .OR. File(cPathXBK+"dtor.dbf") .OR. File(cPathXBK+"wtorg.dbf") .OR. File(cPathXBK+"wdtor.dbf"))
                        EXIT
                    ENDI
                    Inkey(1)
                END
            ELSE
                Inkey(0.5)
            ENDI
            pVirt(5)
        ENDI

        SELE PRE_SELL SKIP
    ENDD
    fDeact( cOldCol )

    //  Восстанавливаю состояние среды программы
    zSet( nOrd )
    DbGoTo( nRec )
    RETU