Форум OlegON > Компьютеры и Программное обеспечение > Операционные системы и программное обеспечение

Автоматическая отправка СМС. : Операционные системы и программное обеспечение

28.03.2024 21:41


18.09.2009 10:04
deleted_user
 
могу поделиться ! для билайна и gmail работает быстро в течении полуминуты
звониш на 06849909 - получаешь почтовый белайновский ящик
скачиваешь вот это и ставишь

Код:
;
;##################################
; Include
;##################################
#Include<file.au3>
;##################################
; Variables
;##################################
$SmtpServer = "smtp.gmail.com"   
$FromName = "твоё имя"                   
$FromAddress = "твой gmail почтовый ящик" 
$ToAddress = "твой beeline почтовый ящик"
$Subject = "тема"                  
$Body = $CmdLine[1]    ; про это ниже                  
$AttachFiles = ""                       
$CcAddress = ""      
$BccAddress = ""     
$Importance = "Normal"                 
$Username = "опять твой gmail почтовый ящик"                 
$Password = "твой gmail пароль"                  
$IPPort = 25                           
$ssl = 1                                

;##################################
; Script
;##################################
Global $oMyRet[2]
Global $oMyError = ObjEvent("AutoIt.Error", "MyErrFunc")
$rc = _INetSmtpMailCom($SmtpServer, $FromName, $FromAddress, $ToAddress, $Subject, $Body, $AttachFiles, $CcAddress, $BccAddress, $Importance, $Username, $Password, $IPPort, $ssl)
If @error Then
    MsgBox(0, "Error sending message", "Error code:" & @error & "  Description:" & $rc)
EndIf
;
; The UDF
Func _INetSmtpMailCom($s_SmtpServer, $s_FromName, $s_FromAddress, $s_ToAddress, $s_Subject = "", $as_Body = "", $s_AttachFiles = "", $s_CcAddress = "", $s_BccAddress = "", $s_Importance="Normal", $s_Username = "", $s_Password = "", $IPPort = 25, $ssl = 0)
    Local $objEmail = ObjCreate("CDO.Message")
    $objEmail.From = '"' & $s_FromName & '" <' & $s_FromAddress & '>'
    $objEmail.To = $s_ToAddress
    Local $i_Error = 0
    Local $i_Error_desciption = ""
    If $s_CcAddress <> "" Then $objEmail.Cc = $s_CcAddress
    If $s_BccAddress <> "" Then $objEmail.Bcc = $s_BccAddress
    $objEmail.Subject = $s_Subject
    If StringInStr($as_Body, "<") And StringInStr($as_Body, ">") Then
        $objEmail.HTMLBody = $as_Body
    Else
        $objEmail.Textbody = $as_Body & @CRLF
    EndIf
    If $s_AttachFiles <> "" Then
        Local $S_Files2Attach = StringSplit($s_AttachFiles, ";")
        For $x = 1 To $S_Files2Attach[0]
            $S_Files2Attach[$x] = _PathFull($S_Files2Attach[$x])
            ConsoleWrite('@@ Debug(62) : $S_Files2Attach = ' & $S_Files2Attach & @LF & '>Error code: ' & @error & @LF) ;### Debug Console
            If FileExists($S_Files2Attach[$x]) Then
                $objEmail.AddAttachment ($S_Files2Attach[$x])
            Else
                ConsoleWrite('!> File not found to attach: ' & $S_Files2Attach[$x] & @LF)
                SetError(1)
                Return 0
            EndIf
        Next
    EndIf
    $objEmail.Configuration.Fields.Item ("sendusing") = 2
    $objEmail.Configuration.Fields.Item ("smtpserver") = $s_SmtpServer
    If Number($IPPort) = 0 then $IPPort = 25
    $objEmail.Configuration.Fields.Item ("smtpserverport") = $IPPort
    ;Authenticated SMTP
    If $s_Username <> "" Then
        $objEmail.Configuration.Fields.Item ("smtpauthenticate") = 1
        $objEmail.Configuration.Fields.Item ("sendusername") = $s_Username
        $objEmail.Configuration.Fields.Item ("sendpassword") = $s_Password
    EndIf
    If $ssl Then
        $objEmail.Configuration.Fields.Item ("smtpusessl") = True
    EndIf
    ;Update settings
    $objEmail.Configuration.Fields.Update
    ; Set Email Importance
    Switch $s_Importance
        Case "High"
            $objEmail.Fields.Item ("urn:schemas:mailheader:Importance") = "High"
        Case "Normal"
            $objEmail.Fields.Item ("urn:schemas:mailheader:Importance") = "Normal"
        Case "Low"
            $objEmail.Fields.Item ("urn:schemas:mailheader:Importance") = "Low"
    EndSwitch
    $objEmail.Fields.Update
    ; Sent the Message
    $objEmail.Send
    If @error Then
        SetError(2)
        Return $oMyRet[1]
    EndIf
    $objEmail=""
EndFunc
;
;
; Com Error Handler
Func MyErrFunc()
    $HexNumber = Hex($oMyError.number, 8)
    $oMyRet[0] = $HexNumber
    $oMyRet[1] = StringStripWS($oMyError.description, 3)
    ConsoleWrite("### COM Error !  Number: " & $HexNumber & "   ScriptLine: " & $oMyError.scriptline & "   Description:" & $oMyRet[1] & @LF)
    SetError(1); something to check for when this function returns
    Return
EndFunc
далеешь файл например mail2sms.au3
компишишь в редакторе: tools - compole
получается экзешник
вот это $CmdLine[1] - параметр командной страки
и запускаешь из cmd
C:\Documents and Settings\Admin>"H:\~CodeAutoIt\mail2sms.exe" "текст письма"
и получаешь всё в течении 30 сек.
и делов то всеголишь :) нужно только интернет там откуда хочешь отправлять ;)
02.02.2010 17:28
omorozov
 
А для МТС такой фичи нет?*04
08.02.2010 02:13
deleted_user
 
Вот нагуглил на быструю руку - http://www.primorye.mts.ru/abonent/services/communication/sms/sms_sendfrom_email/
Часовой пояс GMT +3, время: 21:41.

Форум на базе vBulletin®
Copyright © Jelsoft Enterprises Ltd.
В случае заимствования информации гипертекстовая индексируемая ссылка на Форум обязательна.