[ОТВЕТИТЬ]
Опции темы
21.01.2012 20:25  
OlegON
Слушайте, не нашел, это убожество может снижать или повышать громкость динамиков из командной строки? Только без скачивания чего-то в инете.
 
22.01.2012 14:33  
student
первое что приходит в голову (просто не интересовался ранее) это встроенная команда sndvol(32) - откроет окошко управления громкостью и далее стрелочками вверх\вниз - только окошко закрывать потом придется:connie_tap:

либо попробовать через vbs - wmplayer - его установки вроде бы действуют глобально на звук (код не мой - лежит в архиве давно как образец)
===================
Set WMPlayer = New WMPlayerClass

Dim FilePath

'/// Так же можно указать URl - ссылку на файл в интернете
FilePath = "C:\WINDOWS\Media\chimes.wav"

'/// Открываем ресурс
WMPlayer.OpenMedia FilePath

'/// Выводим длительность файла
msgbox "Длительность файла: " & WMPlayer.CurrentMedia.DurationString,vbInformation,"WMPlayerClass"

'/// проверка изменения громкости
msgbox "Сейчас будет произведена проверка изменения громкости звука. Эффект эхо. 100% 50% 10%"
WMPlayer.Settings.Volume = 100
WMPlayer.Play
WMPlayer.Settings.Volume = 50
WMPlayer.Play
WMPlayer.Settings.Volume = 10
WMPlayer.Play

'/// проверка изменения баланса
MsgBox "Сейчас будет произведена проверка баланса. (левого и правого динамика)",vbInformation,"WMPlayerClass"
WMPlayer.Settings.Volume = 100
WMPlayer.Settings.Balance = -100
WMPlayer.Play
WMPlayer.Settings.Balance = 100
WMPlayer.Play

MsgBox "Проверка завершена.",vbInformation,"WMPlayerClass"

'/// Класс проигрывателя
Class WMPlayerClass
'/// Переменная для хранения ссылки на объект плеера
Dim WMPlayer
Private Sub Class_Initialize()
Set WMPlayer = CreateObject("WMPlayer.OCX")
WMPlayer.settings.autoStart = False
WMPlayer.settings.enableErrorDialogs = False
End Sub

'/// Свойство возвращает ссылку на объект настроек плеера
Public Property Get Settings
Set Settings = WMPlayer.Settings
End Property

'/// Метод подключения к ресурсу
Function OpenMedia(URL)
'/// Несколько из констант состояния открытия
Const wmposMediaLoading = 11
Const wmposMediaLocating = 9
Const wmposPlaylistOpenNoMedia = 6
Const wmposMediaOpen = 13
Const wmposPlaylistOpening = 5
Const wmposOpeningUnknownURL = 21
Const wmposUndefined = 0

'/// Для корректного получения данных о содержимом, нужно открыть ресурс.
WMPlayer.URL = URL
'/// Убираем звук
WMPlayer.settings.mute=true
'/// Запускаем на проигрывание
WMPlayer.controls.Play
'/// Ждём состояния открытия файла. Если файл открыть не удалось вернётся wmposPlaylistOpenNoMedia
Do
WScript.Sleep 10
Loop Until WMPlayer.OpenState = wmposMediaOpen or WMPlayer.OpenState=wmposPlaylistOpenNoMedia
'/// Останавливаем проигрывание
WMPlayer.controls.Stop
'/// Возвращаем звук
WMPlayer.settings.mute=false
End Function

'/// Свойство возвращает ссылку на параметры открытого файла
Public Property Get CurrentMedia
Set CurrentMedia = WMPlayer.CurrentMedia
End Property

'/// Метод запуска проигрывания
Function Play()
WMPlayer.Controls.Play
'/// Ожидаем окончания проигрывания (ждём пока плеер не перейдёт в состояние остановки)
Do
WScript.Sleep 100
Loop Until WMPlayer.playState = 1
End Function
End Class
===================

убрать лишнее и оставить только регулировку звука

либо если юзается специализированный проигрыватель - позырить в его командной строке соответствующие параметры - по идее должны быть
 
23.01.2012 10:00  
OlegON
Спасибо за идею, но я говорил о работе в консоли :( т.е. вообще ssh/telnet... Никакой графики.
 
23.01.2012 10:05  
student
Цитата:
Сообщение от OlegON
Спасибо за идею, но я говорил о работе в консоли :( т.е. вообще ssh/telnet... Никакой графики.
vbs - графики не будет - если не подходит, то тогда только сторонними утилитами (качать придется) - встроенного походу просто нету
 
 
Опции темы



Часовой пояс GMT +3, время: 19:22.

Все в прочитанное - Календарь - RSS - - Карта - Вверх 👫 Яндекс.Метрика
Форум сделан на основе vBulletin®
Copyright ©2000 - 2016, Jelsoft Enterprises Ltd. Перевод: zCarot и OlegON
В случае заимствования информации гипертекстовая индексируемая ссылка на Форум обязательна.