Автоматы: решение задач ЕГАИС без участия пользователей для любых учетных систем посредством "УС Лэнд:ЕГАИС" : КИС Lack & УС Land

* --------------------------------------------------------------------------------------------------
*   Автоматическое создание списка РФУ-2 для последующего запроса остатков регистра №3. Передаётся
*   максимальное число сохраняемых кодов справок в ххх: yzLRFUxxxx, где
*   y = 0 - берем только алкопродукцию принадлежащую регистру №3, иначе всё кроме пива
*   z = 0 - берем, если есть остаток на регистре №1 складе, а иначе скан и закончившейся АП
*   xxx   - максимальное за сеанс выявление числа справок РФУ-2, учитывая что запрос раз в 10 минут
*   Приведенная выше является более гибкой системой посроения списка РФУ-2
*   - Анализируется неиндексированный файл остатков склада. Контрол - номер записи
*   - Делаю только по алкопродукции с остатками и принадлежащей регистру №3. Всё ведём в УСЕга 
PROC pgAuCrList( cPar )
    LOCA cM:="", lR3:=FALSE, cB:="", cStr:="", lBof:=FALSE, nBegRec:=0, nCount:=0, nRec:=0, lNew:=TRUE
    LOCA nR3:=0, nRest:=0, nMax:=0, cFile:="ListRFU2.TXT"
    
    //  Разбираем переданный параметр
    nR3     := Val(Subs(cPar,1,1))
    nRest   := Val(Subs(cPar,2,1))
    IF (nMax:=Val(Subs(cPar,7)))<=0 THEN pCloseUSega(); fErr_Quit("Не задано максимальное количество РФУ-2 в списке!",cError)
        
    //  Работа автомата возможна лишь при открытых таблицах программы - иначе прекращение работы
    IF !lOpenMyDbf() THEN pCloseUSega(); fErr_Quit("Не доступна или отключено ведение БД программы - дальнейшая работа не возможна!",cError)

    //  Определяю последнюю обработанную запись из предыдущего запуска автомата
    nBegRec := Val(cgGetValue("LISTRFU2"))
    
    //  Устанавливаем рабочие индексы для работы и начинаем скан остатков склада
    SELE MY_RESTS
    DbSetOrder(0)
    
    //  Для предотвращения зацикливания определяю начальные установки от возможно предыдущего запуска
    lBof    := (nBegRec <= 0)
    DbGoTo( nBegRec )
    IF Eof()
        nBegRec := 0
        lBof    := TRUE
    ENDI
    IF lBof
        DbGoTop()
    ELSE
        DbSkip()
    ENDI
    
    //***   Поехали. Возможно возвращение на начало - ловим момент завершения в теле
    nRec    := RecNo()
    DO WHIL TRUE
    
        //  Блок отсева. Возможно, что ни одна запись не будет удовлетворять условиям
        IF Eof()                //  Достигли конца
            
            //  Ничего не подобрали
            IF nCount <= 0  THEN EXIT
            
            //  Начинали подбор с начала и прошли таблицу до конца
            IF lBof         THEN EXIT
            
            //  Начинаем с начала таблицы
            DbGoTop(); LOOP
        ENDI
        
        //  Пошли на второй круг при старте со средины
        IF !lNew .AND. (Abs(RecNo()-nRec)<0.001) THEN EXIT
        lNew    := FALSE
        
        //  Блок отсева записей по условиям вызова автомата
        IF (nRest <= 0) .AND. (qtyAll <= 0)                 //  Отбор только с остатками на регистре №1
            DbSkip(); LOOP
        ENDI
        
        //  Всегда отсеиваю пиво, считая его не маркированной алкопродукцией
        IF !lgUslPivo(MY_RESTS->codAlc,1)
            DbSkip(); LOOP
        ENDI
        
        //  Отсев по признаку принадлежности регистру №3 по записям в таблице пула марок
        cB      := Alltrim(numbb)
        
        //  Отсев по принадлежности регистру №3 по информации из пула
        IF nR3 <= 0
            lR3 := lgR3Marka(MY_RESTS->regId,cB,@cM)
            IF !lR3 THEN DbSkip(); LOOP
        ENDI
        
        cStr    += cB+CRLF                                  //  Подготавливаю строку для записи в файл
        IF ++nCount >= nMax                                 //  Выбрали требуемое число справок
            EXIT
        ENDI
        DbSkip()
    ENDD
    
    //  Запоминаю запись в таблице остатков на которой остановились
    lgPutValue("LISTRFU2",Alltrim( Str(MY_RESTS->(RecNo()),19) ))
    
    //  Сохраняю в текстовый файл каталога программы
    MemoWrit( HB_OEMTOANSI(cFile), HB_OEMTOANSI(cStr) )
    pCloseUSega()
    fErr_Quit("Сохранено в "+cFile,cMainc)
    RETU